;ledbpgp2s
;avance-version (12/01/11)
;2D sequence for diffusion measurement using stimulated 
;   echo and LED
;using bipolar gradient pulses for diffusion
;using 2 spoil gradients
;
;D. Wu, A. Chen & C.S. Johnson Jr., 
;   J. Magn. Reson. A 115, 260-264 (1995).
;
;$CLASS=HighRes
;$DIM=2D
;$TYPE=
;$SUBTYPE=
;$COMMENT=


#include <Avance.incl>
#include <Grad.incl>
#include <Delay.incl>


define list<gradient> diff=<Difframp>


"p2=p1*2"


"DELTA1=d20-p1*2-p2-p30*2-d16*2-p19-d16"
"DELTA2=d21-p19-d16-4u"


"acqt0=-p1*2/3.1416"


1 ze
2 d1
  50u UNBLKGRAD
  p1 ph1
  p30:gp6*diff
  d16
  p2 ph1
  p30:gp6*-1*diff
  d16
  p1 ph2
  p19:gp7
  d16
  DELTA1
  p1 ph3
  p30:gp6*diff
  d16
  p2 ph1
  p30:gp6*-1*diff
  d16
  p1 ph4
  p19:gp8
  d16
  DELTA2
  4u BLKGRAD
  p1 ph5
  go=2 ph31
  d1 mc #0 to 2 F1QF(calgrad(diff))
exit


ph1= 0
ph2= 0 0 2 2
ph3= 0 0 0 0 2 2 2 2  1 1 1 1 3 3 3 3
ph4= 0 2 0 2 2 0 2 0  1 3 1 3 3 1 3 1
ph5= 0 0 0 0 2 2 2 2  1 1 1 1 3 3 3 3
ph31=0 2 2 0 2 0 0 2  3 1 1 3 1 3 3 1


;pl1 : f1 channel - power level for pulse (default)
;p1  : f1 channel -  90 degree high power pulse
;p2  : f1 channel - 180 degree high power pulse
;p19: gradient pulse 2 (spoil gradient)
;p30: gradient pulse (little DELTA * 0.5)
;d1  : relaxation delay; 1-5 * T1
;d16: delay for gradient recovery
;d20: diffusion time (big DELTA)
;d21: eddy current delay (Te)			[5 ms]
;ns: 8 * n
;ds: 4 * m
;td1: number of experiments
;FnMODE: QF
;        use xf2 and DOSY processing


;use gradient ratio:    gp 6 : gp 7   : gp 8
;                       100  : -17.13 : -13.17

;for z-only gradients:
;gpz6: 100%
;gpz7: -17.13% (spoil)
;gpz8: -13.17% (spoil)

;use gradient files:   
;gpnam6: SMSQ10.100
;gpnam7: SMSQ10.100
;gpnam8: SMSQ10.100

;use AU-program dosy to calculate gradient ramp-file Difframp



;$Id: ledbpgp2s,v 1.8 2012/01/31 17:49:27 ber Exp $